Last published: May 1, 2012 by 'lukas'
After the *announcement>http://www.iam.unibe.ch/pipermail/moose-dev/2010-February/003956.html* in the Moose mailing list and after *various>http://damiencassou.seasidehosting.st/* *people>http://stephane.ducasse.free.fr/* *have>http://www.tudorgirba.com/* asked me to provide some introduction to PetitParser I decided to write short tutorial.
Originally I have written PetitParser as part of my work on the *Helvetia>http://scg.unibe.ch/research/helvetia* system. PetitParser is a parsing framework different to many other popular parser generators. For example, it is not table based such as *SmaCC>http://www.refactory.com/Software/SmaCC/index.html* or *ANTLR>http://www.antlr.org/*. Instead it uses a unique combination of four alternative parser methodologies: scannerless parsers, parser combinators, parsing expression grammars and packrat parsers. As such PetitParser is more powerful in what it can parse and it arguably fits better the dynamic nature of Smalltalk. Let's have a quick look at these four parser methodologies:
# ''Scannerless Parsers'' combine what is usually done by two independent tools (scanner and parser) into one. This makes writing a grammar much simpler and avoids common problems when grammars are composed.
# ''Parser Combinators'' are building blocks for parsers modeled as a graph of composable objects; they are modular and maintainable, and can be changed, recomposed, transformed and reflected upon.
# ''Parsing Expression Grammars'' (PEGs) provide ordered choice. Unlike in parser combinators, the ordered choice of PEGs always follows the first matching alternative and ignores other alternatives. Valid input always results in exactly one parse-tree, the result of a parse is never ambiguous.
# ''Packrat Parsers'' give linear parse time guarantees and avoid common problems with left-recursion in PEGs.
!! Loading PetitParser
Enough theory, let's get started. PetitParser is developed in *Pharo>http://www.pharo-project.com*, but is also available on other Smalltalk platforms. A ready made image can be downloaded *here>http://hudson.lukas-renggli.ch/job/PetitParser/lastSuccessfulBuild/artifact/petitparser/%2Azip%2A/petitparser.zip*. To load PetitParser into an existing image evaluate the following Gofer expression:
== renggli: 'petit';
== package: 'PetitParser';
There are other packages in the same repository that provide additional features, for example ==PetitSmalltalk== is a Smalltalk grammar, ==PetitXml== is an XML grammar, ==PetitAnalizer== can perform analysis on grammars, and ==PetitGui== is a Glamour IDE for writing complex grammars. We are not going to use any of these packages for now.
More information on how to get PetitParser can be found on the *website>http://scg.unibe.ch/research/helvetia/petitparser* of the project.
!! Writing a Simple Grammar
Writing grammars with PetitParser is simple as writing Smalltalk code. For example to write a grammar that can parse identifiers that start with a letter followed by zero or more letter or digits is defined as follows. In a workspace we evaluate:
== identifier := #letter asParser , #word asParser star.
If you inspect the object ==identifier== you'll notice that it is an instance of a ==PPSequenceParser==. This is because the ==#,== operator created a sequence of ''a letter'' and ''a zero or more word character'' parser. If you dive further into the object you notice the following simple composition of different parser objects:
= PPSequenceParser (this parser accepts a sequence of parsers)
= PPPredicateObjectParser (this parser accepts a single letter)
= PPRepeatingParser (this parser accepts zero or more instances of another parser)
= PPPredicateObjectParser (this parser accepts a single word character)
!! Parsing Some Input
To actually parse a string (or stream) we can use the method ==#parse:==:
== identifier parse: 'yeah'. " --> #($y #($e $a $h)) "
== identifier parse: 'f12'. " --> #($f #($1 $2)) "
While it seems odd to get these nested arrays with characters as a return value, this is the default decomposition of the input into a parse tree. We'll see in a while how that can be customized.
If we try to parse something invalid we get an instance of ==PPFailure== as an answer:
== identifier parse: '123'. " --> letter expected at 0 "
Instances of ==PPFailure== are the only objects in the system that answer with ==true== when you send the message ==#isPetitFailure==. Alternatively you can also use ==#parse:onError:== to throw an exception in case of an error:
== parse: '123'
== onError: [ :msg :pos | self error: msg ].
If you are only interested if a given string (or stream) matches or not you can use the following constructs:
== identifier matches: 'foo'. " --> true "
== identifier matches: '123'. " --> false "
Furthermore to find all matches in a given input string (or stream) you can use:
== identifier matchesIn: 'foo 123 bar12'.
!! Different Kinds of Parsers
PetitParser provide a large set of ready-made parser that you can compose to consume and transform arbitrarily complex languages. The terminal parsers are the most simple ones. We've already seen a few of those:
|! Terminal Parsers |! Description
| ==$a asParser== | Parses the character ==$a==.
| =='abc' asParser== | Parses the string =='abc'==.
| ==#any asParser== | Parses any character.
| ==#digit asParser== | Parses the digits 0..9.
| ==#letter asParser== | Parses the letters a..z and A..Z.
The class side of ==PPPredicateObjectParser== provides a lot of other factory methods that can be used to build more complex terminal parsers.
The next set of parsers are used to combine other parsers together:
|! Parser Combinators |! Description
| ==p1 , p2== | Parses ==p1== followed by ==p2== (sequence).
| ==p1 / p2== | Parses ==p1==, if that doesn't work parses ==p2== (ordered choice).
| ==p star== | Parses zero or more ==p==.
| ==p plus== | Parses one or more ==p==.
| ==p optional== | Parses ==p== if possible.
| ==p and== | Parses ==p== but does not consume its input.
| ==p not== | Parses ==p== and succeed when ==p== fails, but does not consume its input.
| ==p end== | Parses ==p== and succeed at the end of the input.
So instead of using the ==#word== predicated we could have written our identifier parser like this:
== identifier := #letter asParser , (#letter asParser / #digit asParser) star.
To attach an action or transformation to a parser we can use the following methods:
|! Action Parsers |! Description
| ==p \==> aBlock== | Performs the transformation given in ==aBlock==.
| ==p flatten== | Creates a string from the result of ==p==.
| ==p token== | Creates a token from the result of ==p==.
| ==p trim== | Trims whitespaces before and after ==p==.
To return a string of the parsed identifier, we can modify our parser like this:
== identifier := (#letter asParser , (#letter asParser / #digit asParser) star) flatten.
These are the basic elements to build parsers. There are a few more well documented and tested factory methods in the ==operations== protocol of ==PPParser==. If you want browse that protocol.
!! Writing a More Complicated Grammar
Now we are able to write a more complicated grammar for evaluating simple arithmetic expressions. Within a workspace we start with the grammar for a number (actually an integer):
== number := #digit asParser plus token trim ==> [ :token | token value asNumber ].
Then we define the productions for addition and multiplication in order of precedence. Note that we instantiate the productions as ==PPUnresolvedParser== upfront, because they recursively refer to each other. The method ==#def:== resolves this recursion using the reflective facilities of the host language:
== term := PPUnresolvedParser new.
== prod := PPUnresolvedParser new.
== prim := PPUnresolvedParser new.
== term def: (prod , $+ asParser token trim , term ==> [ :nodes | nodes first + nodes last ])
== / prod.
== prod def: (prim , $* asParser token trim , prod ==> [ :nodes | nodes first * nodes last ])
== / prim.
== prim def: ($( asParser token trim , term , $) asParser token trim ==> [ :nodes | nodes second ])
== / number.
To make sure that our parser consumes all input we wrap it with the ''end'' parser into the start production:
== start := term end.
That's it, now we can test our parser and evaluator:
== start parse: '1 + 2 * 3'. " --> 7 "
== start parse: '(1 + 2) * 3'. " --> 9 "
As an exercise we could extend the parser to also accept negative numbers and floating point numbers, not only integers. Furthermore it would be useful to add support subtraction and division as well. All these features can be added with a few lines of PetitParser code.